求恶魔SS和痛苦术士的输出宏 我是亡灵术士。

求恶魔`痛苦SS各种宏~

壹---宠物&宠物技能套宏&分解宏---共两个套宏，恶魔一套，痛苦、毁灭一套。


一、一键控制宠物技能+顺招套宏，恶魔术专用。（原创）
注意：所有的套宏都需要按照要求放在指定的动作条按钮上！！！其实这两个套宏我已经写出来很久了，一直在排错中，现在功能比较完善，并且暂时没有发现什么错误，所以才发上来让大家用。如果你是个宏小白，那么请你一定要按照步骤一步一步来做。
首先，键4个宏如下面的1、2、3、4、5~
1111111111
/click [button:1]MultiBarBottomLeftButton2
/click [button:1]MultiBarBottomLeftButton3
/click [nopet,button:1][target=pet,dead,button:1]MultiBarBottomLeftButton4
/click [button:2]MultiBarBottomLeftButton5
/cast [nopet,button:3]召唤小鬼
/cast [pet,button:3]灵魂链接

2222222222
/cast [nomodifier]牺牲;[nocombat,modifier:alt]吞噬暗影
/cast [modifier:shift,target=focus][target=mouseover,harm,nomodifier][harm,nomodifier]法术封锁
/cast [modifier:shift,target=focus][target=mouseover][harm]诱惑

3333333333
/cast [modifier:alt,target=player][target=mouseover,help,nomodifier][help,nomodifier]吞噬魔法
/cast [modifier:shift,target=focus][target=mouseover][harm]拦截
/cast [help][target=player]火焰之盾

4444444444
# show 恶魔支配
/cast [nopet][target=pet,dead]恶魔支配
/stopcasting
/cast [nomodifier]召唤虚空行者;[modifier:shift,nomodifier:alt,nomodifier:ctrl]召唤恶魔卫士;[modifier:alt,nomodifier:shift,nomodifier:ctrl]召唤地狱猎犬;[modifier:ctrl,nomodifier:alt,nomodifier:shift]召唤魅魔

5555555555
/cast [nomodifier]召唤虚空行者;[modifier:shift,nomodifier:alt,nomodifier:ctrl]召唤恶魔卫士;[modifier:alt,nomodifier:shift,nomodifier:ctrl]召唤地狱猎犬;[modifier:ctrl,nomodifier:alt,nomodifier:shift]召唤魅魔

宏键完之后，把宏2放在左下动作条按钮2上，把宏3放在左下动作条按钮3上，把宏4放在左下动作条4上，把5放在左下动作条按钮5上面！
最后，把1放在你设置的快捷键上，也就是你要使用这个宏的时候所要按的按钮上！

说明：
这个套宏把瞬招胖子牺牲宏、狗吞噬自身魔法宏都整合了进来。并且其他的宠物技能以及各种宠物的召唤，还有灵魂链接也都整合了进来，能节省的快捷键真的很多（具体多少没数）。。。具体情况如下：
1、当前无宠物：按住alt+左键召唤狗，按住ctrl+左键召唤MM，按住shift+左键召唤恶魔卫士，什么也不按是召唤虚空，鼠标中键点是召唤小鬼。哦```忘了说了，除了小鬼都是瞬招```
如果当前有宠物，按组合键+左键并不会召唤宠物，但是组合键+鼠标右键可以。鼠标中键为灵魂链接。
2、有宠物的时候，右键点宏是灵魂链接。
是虚空的时候牺牲并且再瞬招出来一个！
是MM的时候诱惑。
是卫士的时候拦截。
是小鬼的时候，如果目标为友善就对目标放火焰盾，否则就对自己放火焰盾。
是狗的时候，如果目标是敌对的就放法术封锁，是友善的就吞噬魔法，按住alt是吃自己的DEBUFF~
注意！！！所有的宠物技能都是优先对鼠标指向施放！！！按住shift是对焦点目标施放（也就是锁定的目标）！！！
3、DIY手册：
---宏中的红色部分为召唤宠物时所需要按的组合键名称，可以随自己喜欢修改为ctrl、alt、shift其中之一。“nomodifier”为不需要组合按键。
---宏中的蓝色部分为2、3、4宏所需要指定放置的按钮编号。比如你想把2号宏放在主动作条的第2个按钮内，那么就把上面的“MultiBarBottomLeftButton1”改成“ActionButton2”。具体参照下面给出的动作条名称及按钮编号。
动作条名称以及编号：
主动作条1：ActionButton
主动作条2：不知道。。。。。。。
主动作条3（右1）：MultiBarRightButton
主动作条4（右2）：MultiBarLeftButton
主动作条5（右下）：MultiBarBottomRightButton
主动作条6（左下）：MultiBarBottomLeftButton
每个动作条按钮的编号都是从左至右1~12。


----------------------------------------------------------------------------------------------------------
----------------------------------------------------------------------------------------------------------


二、宠物控制+召唤套宏，适合痛苦、毁灭。（原创）
首先，键4个宏如下面的1、2、3、4、5~
1111111111
/click [button:1]MultiBarBottomLeftButton2
/click [button:1]MultiBarBottomLeftButton3
/click [nopet,button:1][target=pet,dead,button:1]MultiBarBottomLeftButton4
/click [button:2]MultiBarBottomLeftButton5
/cast [button:3]召唤小鬼

2222222222
/cast 牺牲;[nocombat,modifier:alt]吞噬暗影
/cast [modifier:shift,target=focus][target=mouseover,harm,nomodifier][harm,nomodifier]法术封锁
/cast [modifier:shift,target=focus][target=mouseover][harm]诱惑

3333333333
/cast [modifier:alt,target=player][target=mouseover,help,nomodifier][help,nomodifier]吞噬魔法
/cast [help][target=player]火焰之盾

4444444444
/cast [nomodifier]召唤虚空行者;[modifier:alt,nomodifier:shift,nomodifier:ctrl]召唤地狱猎犬;[modifier:shift,nomodifier:alt,nomodifier:ctrl]召唤魅魔

5555555555
/cast [nomodifier]召唤虚空行者;[modifier:shift,nomodifier:alt,nomodifier:ctrl]召唤恶魔卫士;[modifier:alt,nomodifier:shift,nomodifier:ctrl]召唤地狱猎犬;[modifier:ctrl,nomodifier:alt,nomodifier:shift]召唤魅魔

宏键完之后，把宏2放在左下动作条按钮2上，把宏3放在左下动作条按钮3上，把宏4放在左下动作条4上，把5放在左下动作条按钮5上面！
最后，把1放在你设置的快捷键上，也就是你要使用这个宏的时候所要按的按钮上！

说明：
这个套宏整合了狗的吞噬自身魔法以及其他的宠物技能和各种宠物的召唤。具体如下：
1、当前无宠物：按住alt+左键召唤狗，按住shift+左键召唤MM，只按鼠标右键召唤虚空，只按鼠标中键点是召唤小鬼。
如果当前有宠物，按组合键+左键并不会召唤宠物，但是组合键+鼠标右键可以。
2、是虚空的时候牺牲。
是MM的时候诱惑。
是小鬼的时候，如果目标为友善就对目标放火焰盾，否则就对自己放火焰盾。
是狗的时候，如果目标是敌对的就放法术封锁，是友善的就吞噬魔法，按住alt是吃自己的DEBUFF~
注意！！！所有的宠物技能都是优先对鼠标指向施放！！！按住shift是对焦点目标施放（也就是锁定的目标）！！！
3、DIY手册：
---宏中的红色部分为召唤宠物时所需要按的组合键名称，可以随自己喜欢修改为ctrl、alt、shift其中之一。“nomodifier”为不需要组合按键。
---宏中的蓝色部分为2、3、4宏所需要指定放置的按钮编号。比如你想把2号宏放在主动作条的第2个按钮内，那么就把上面的“MultiBarBottomLeftButton1”改成“ActionButton2”。具体参照下面给出的动作条名称及按钮编号。
动作条名称以及编号：
主动作条1：ActionButton
主动作条2：不知道。。。。。。。
主动作条3（右1）：MultiBarRightButton
主动作条4（右2）：MultiBarLeftButton
主动作条5（右下）：MultiBarBottomRightButton
主动作条6（左下）：MultiBarBottomLeftButton
每个动作条按钮的编号都是从左至右1~12。


----------------------------------------------------------------------------------------------------------
----------------------------------------------------------------------------------------------------------


三---宠物攻击、跟随与自动施放组宏（原创）
1111111111---宠物攻击宏
/petattack
/petdefensive
/petautocaston [modifier:shift]吞噬魔法;[modifier:alt]法术封锁;[modifier:shift]拦截
/petautocaston [modifier:alt]吞噬魔法
/petautocastoff [modifier:shift]法术封锁
宠物攻击+防御和宠物技能自动施放绑定的宏。按住shift时会在攻击的同时把吞噬魔法或拦截的自动施放打开；按住alt会把法术封锁和吞噬魔法的自动施放一起打开。


2222222222---宠物跟随宏
/petfollow [nomodifier]
/petpassive [nomodifier]
/petstay [modifier:alt]
/petautocastoff [modifier:shift]吞噬魔法;拦截
/petautocastoff [modifier:shift]法术封锁
宠物跟随（按住alt为停留）+被动和宠物技能自动释放关闭绑定的宏。按住shift跟随+被动的同时把吞噬魔法、法术封锁或者拦截的自动施放关闭，不按shift则不执行关闭动作。


3333333333---可以不改变目标打图腾的宠物攻击宏
/petattack
/petattack [target=根基图腾][target=战栗图腾][target=图腾]
/petdefensive
/petautocaston [modifier:shift]吞噬魔法;[modifier:alt]法术封锁;[modifier:shift]拦截
/petautocaston [modifier:alt]吞噬魔法
/petautocastoff [modifier:shift]法术封锁
这个宏可以说是宠物攻击+防御和宠物技能自动施放绑定的宏，并且在攻击时自动搜索图腾为首先的攻击目标。图腾的优先级为根基>战栗>其他图腾。按住shift时会在攻击的同时把吞噬魔法或拦截的自动施放打开；按住alt会把法术封锁和吞噬魔法的自动施放一起打开。


4444444444---宠物攻击、跟随、停留一键控制宏
/petattack [target=pettarget,noexists]
/petfollow [target=pettarget,exists]
/petstay [pet:魅魔,target=pettarget,exists]
如果宠物当前在跟随或者停留就攻击，反之则跟随（如果宠物是MM就停留）。


----------------------------------------------------------------------------------------------------------
----------------------------------------------------------------------------------------------------------


四、分解宏（原创）
1111111111---诱惑
/cast [modifier:shift,target=focus][target=mouseover]诱惑
优先对鼠标指向的目标施放，如果鼠标无指向就对目标施放，按住shift对锁定的目标施放。


2222222222---法术封锁
/cast [modifier:shift,target=focus][target=mouseover]法术封锁
优先对鼠标指向的目标施放，如果鼠标无指向就对目标施放，按住shift对锁定的目标施放。


3333333333---吞噬魔法
/cast [modifier:alt,target=player][target=mouseover]吞噬魔法
优先对鼠标指向的目标施放，如果鼠标无指向就对目标施放，按住alt吃自己的DEBUFF。


4444444444---拦截
/cast [modifier:shift,target=focus][target=mouseover]拦截
优先对鼠标指向的目标施放，如果鼠标无指向就对目标施放，按住shift对锁定的目标施放。


5555555555---法术封锁+吞噬魔法
/cast [modifier:shift,target=focus][target=mouseover,harm,nomodifier][harm,nomodifier]法术封锁;[modifier:alt,target=player][help,nomodifier]吞噬魔法
简单并且使用性非常高的一个宏。目标为敌对就使用法术封锁，按住shift对锁定目标使用法术封锁。目标为友善就使用吞噬魔法，按住alt就对自己使用吞噬魔法。


6666666666---瞬招+牺牲
/cast [nopet,target=pet,dead]恶魔支配;牺牲
/stopcasting
/cast 召唤虚空行者
宠物不是虚空的时候点一下召唤虚空行者，宠物是虚空行者的时候点一下直接牺牲+瞬招。


7777777777---宝宝打图腾宏
/petattack
/petattack [target=根基图腾][target=战栗图腾][target=图腾]
在不改变当前目标的情况下宠物打图腾。优先顺序为根基>战栗>其他图腾。


8888888888---宠物技能一键整合宏壹
/cast 牺牲
/cast [target=mouseover]诱惑
/cast [target=mouseover]火焰之盾
/cast [target=mouseover]拦截
/cast [target=mouseover][harm]法术封锁;[help]吞噬魔法
宠物技能一键控制。当前宠物是MM就使用诱惑，是虚空就牺牲，是小鬼就使用火焰之盾，是卫士就使用拦截。是狗，如果目标为敌对就封锁，为友善就吞噬魔法。除吞噬魔法外其他法术优先鼠标指向，各种天赋通用。


9999999999---宠物技能一键整合宏贰
/cast 吞噬暗影
/cast [target=player]火焰之盾
/cast [target=player]吞噬魔法
/cast [target=mouseover]顺劈斩
/cast [target=mouseover]剧痛鞭笞
宠物技能一键控制。当前宠物是MM就使用鞭笞，是虚空就使用吞噬暗影，是小鬼就对自己施放火焰之盾，是卫士就使用顺劈斩。是狗就吞噬自己身上的魔法。顺辟和鞭笞优先鼠标指向，各种天赋通用。


1000000000---宠物技能一键整合宏贰
/cast 火焰之盾
/cast [target=mouseover]诱惑
/cast [target=mouseover]拦截
/cast [modifier:alt]吞噬暗影;牺牲
/cast [target=mouseover,nomodifier][nomodifier,harm]法术封锁;
[modifier:alt,target=player][modifier:shift,harm][help]吞噬魔法
宠物是小鬼就施放火焰之盾；是MM就诱惑（支持鼠标指向）；是卫士就拦截（支持鼠标指向）；是虚空，按住alt是吞噬暗影，不按就是牺牲；是狗，按住alt吃自己DEBUFF，按住shift吃敌对目标的BUFF，目标是友善的时候就吃目标的DEBUFF。如果目标为敌对就施放法术封锁（支持鼠标指向）。


贰---石头+药水+绷带+面包+水


一、吃东西“？”（原创）
# show 特效治疗石
/use [combat]特效治疗石
/use [combat]强效治疗石
/use [combat]作战治疗药水
/use [combat]特效治疗药水
/cast [nocombat,noharm,button:1]制造治疗石; [button:2]制造治疗石(等级 4)
看名字就明白了吧~吃石头和药水的宏。在战斗就吃药水+石头，不在战斗就制造特效石头。鼠标右键点制造强效石头。


二、魔杖&法术石“？”（原创）
1111111111
/cast [button:2]制造法术石
/stopcasting [button:1]
/cast [nomodifier,equipped:魔杖,harm]射击;[nomodifier,equipped:圣物,combat]特效法术石
/equip [modifier:alt][combat]雷特森的魔晶手杖;[modifier:shift][nocombat]特效法术石
魔杖/法术石一键控制。
1、如果你装备的是魔杖并且目标可以攻击就是射击，否则使用法术石（战斗中），并且在使用完法术石之后再把魔杖装备上。
2、鼠标右键点宏制造石头。
3、按住shift无论在什么情况下都装备法术石，按住alt无论在什么情况下都装备魔杖。
4、褂檬鼻胱孕懈�哪д群头ㄊ跏�拿�帧�/color]


[color=Green]2222222222
/cast [button:2]制造法术石
/stopcasting [button:1]
/cast [equipped:魔杖,modifier:shift]射击;[equipped:圣物,nomodifier]特效法术石
/equip [noequipped:魔杖,modifier:shift]雷特森的魔晶手杖;[noequipped:圣物,nomodifier]特效法术石
其实这个宏就是为了节省一个按钮位置。
1、按住shift射击（没装备魔杖就装备，再按才射击），不按组合键就使用法术石（同样是没装备就装备）。
2、鼠标右键点宏制造法术石。
3、使用时请自行更改魔杖和法术石的名字。


三、灵魂石“？”（官方蓝贴给出的变形版）
# show 特效灵魂石
/cast [button:3,target=player] 特效灵魂石; [button:1] 特效灵魂石; [button:2] 制造灵魂石
灵魂石宏，右键制作灵魂石，左键绑定目标，鼠标滚轮向下按绑定自己（使用时需要把按键设置最上面“移动控制”鼠标中键解除）。


四、增强型自动绷带宏（summer699 MOP，说明全部引用原文）
#showtooltip 厚符文布绷带
/use [help] 战歌峡谷符文布绷带; [target=player] 战歌峡谷符文布绷带
/use [help] 污染者的符文布绷带; [target=player] 污染者的符文布绷带
/use [help] 奥特兰克厚符文布绷带; [target=player] 奥特兰克厚符文布绷带
/use [help] 厚符文布绷带; [target=player] 厚符文布绷带
说明：这个是智能型一键绑所有战场和普通绷带的宏！不用再换绷带到技能栏了.一键搞定，效果和第一个一样！可以实现当无目标或者目标是敌人时，会不改变当前目标对自己施加绷带，但当目标是队友时，会帮队友绑绷带。进任何战场自动使用该战场型号绷带，该战场绷带用完时就自动转用厚符文绷带，贼不掉星。


叁---控制&反控制


一、恐惧&放逐（原创）
1111111111---锁定目标版
/clearfocus [target=focus,dead][modifier:alt,exists]
/focus [target=focus,noexists]
/cast [modifier:shift,nomodifier:alt,nomodifier:ctrl,target=focus][nomodifier,target=mouseover]恐惧
说明：
1、如果你当前没有锁定任何目标，那么这个宏会帮你锁定当前目标并恐惧他，如果鼠标有指向，那么会先恐惧鼠标指向的目标而不会锁定他。当你再使用宏时，除非刚才被锁定的那个目标死了或者你按住了alt才会再重新锁定当前目标，否则是不会再重新锁定的。
2、如果你之前已经锁定了一个目标，那么按住shift会恐惧被锁定的目标。
3、另外，恐惧可改成放逐，我的恐惧和放逐都是这个宏。


2222222222---锁定鼠标指向版
/clearfocus [target=focus,dead][modifier:alt,target=mouseover,exists]
/focus [target=focus,noexists]mouseover
/cast [modifier:shift,target=focus][target=mouseover]恐惧
1、这个宏只会锁定鼠标指向的目标并且恐惧他，如果你的鼠标指向没有目标，那么会恐惧你当前的目标，但是并不锁定当前目标。
2、如果你之前已经锁定了一个目标（未死亡），按住alt为重新锁定一个目标，按住shift会恐惧被锁定的目标。
3、另外，恐惧可改成放逐，我的恐惧和放逐都是这个宏。


3333333333---锁定任何目标版
/clearfocus [target=focus,dead][modifier:alt,target=mouseover,exists][modifier:alt,exists]
/focus [target=focus,noexists]mouseover
/focus [target=focus,noexists]
/cast [modifier:shift,target=focus][target=mouseover]恐惧
1、如果你当前没有锁定任何目标，那么这个宏会帮你锁定鼠标指向或当前目标并恐惧他。也就是说优先鼠标指向。
2、如果你之前已经锁定了一个目标（锁定目标未死亡），按住alt为重新锁定另一个目标。按住shift会恐惧被锁定的目标。
3、另外，恐惧可改成放逐，我的恐惧和放逐都是这个宏。


二、放逐（官方蓝贴给出的变形版）
/cast [modifier:alt,nomodifier:shift,nomodifier:ctrl,target=mouseover]放逐术(等级 1);[target=mouseover]放逐术
如果鼠标有指向就放逐鼠标指向的目标，没有就放逐当前目标。按住alt为1级放逐，不按为最高等级的放逐。


三、徽章+意志“？”（原创）
/castsequence reset=120/alt 13,亡灵意志
虽然不能判断法术冷却了，但是我们可以变相的实现某些功能。。。
这个宏的作用实际就是按顺序使用法术和物品（13代表身上装备槽的第13个，也就是上方的饰品）。
先用徽章，如果徽章在冷却中就使用意志。前提是必须把徽章带在上方饰品的位置。并且这个宏是针对2M冷却的徽章使用，如果你的徽章是5M的，就把120改成300。按住alt重置宏。
虽然这个宏看着很不错，但是由于现在徽章对于PVP的重要性，经常打战场和竞技场的朋友还是不要使用这个宏为上。徽章用来解了上次的恐惧却解不了现在盗贼的晕启不是一件很郁闷的事情。


四、暗影之怒+炸弹“？”
/castsequence reset=20 暗影之怒,瑟银手榴弹
暗怒不在CD就暗怒，在CD就使用手雷。貌似很实用。原创作者未知，我想很多会写宏的毁灭术士人都可以自己写出这个宏。

/目标 (自己名字）
/施放 吞噬魔法

就简单做几个爆发宏，毕竟术士三系都是优先级输出，没有循环宏
起手爆发（仅限于开始带恶魔卫士，另，我试过只有小逗号能够使宏正常使用）
#showtooltip
/petattack
/castsequence reset=9/combat 恶魔之魂,灵魂燃烧,召唤地狱猎犬

起手循环（恶魔，最好近战，仅仅BOSS起手循环）
#showtooltip
/petattack
/castsequence reset=9/combat 元素诅咒,献祭,腐蚀术,暗影烈焰,末日灾祸,古尔丹之手

起手循环（痛苦，要求同上）
#showtooltip
/petattack
/castsequence reset=9/combat 痛苦无常,鬼影缠身,腐蚀术,末日灾祸

注意，元素诅咒之所以不加入循环因为施加诅咒效果后会呈现出一个光环性的debuff。假如BOSS战双目标或者多目标，一般挂在最多血的怪身上，这样子怪周围40码都会出现相同的诅咒效果。

灵魂之火（4T13）
/CAST 灵魂之火
/cast 灵魂燃烧

恶魔变形+献祭光环
#showtooltip
/petattack
/castsequence reset=9/combat 恶魔变形,献祭光环（恶魔变形）

可通过在下一行（/use 饰品） 加多个主动触发饰品，不过容易造成显示CD混乱。

目标宏（对指定目标施法）
/目标 指定目标
/cast 法术

实际上宏可以中英文混合使用。相对来说恶魔容易做宏，痛苦主要是转目标比较多，适合使用目标宏。
暂时先发这么多。如果需要加上某些天赋技能，可以另开一行通过（/cast 技能）实现

恶魔只需要个起手宏，痛苦不需要，输出宏还是别要了，影响DPS的，因为输出宏要是你的急速有剩余或者不够就会很浪费

SS感觉痛苦SS不用什么宏吧。。。就那几个DOT。。。按按就行了。。如果有宏的话机动能力可能会变的有些差。。不然手动来的快哦

还是多设置些快捷键 术士的DOT如果做宏的话不好调整时间、节奏 起手宏倒是可以做一下

你把你看的宏发给我，我可以给你改成你用的。

你可以帮我看一下我现在的宏怎么样么？

#showtooltip
/petattack
/startattack
/castsequence [mod] reset=9 灵魂之火;烧尽
/castsequence reset=9/combat/target 献祭,元素诅咒,$
/castsequence reset=9/combat 腐蚀术,末日灾祸,古尔丹之手,腐蚀术,古尔丹之手,腐蚀术,古尔丹之手,腐蚀术,古尔丹之手,腐蚀术,古尔丹之手
恶魔的宏 卡古尔的CD 就这样输出怎么样？
这个没有加收人的种族天赋。。。反正和兽人不兽人没有关系。要是有人能用，你也能用。
如果这个宏没有问题，这是三个宏吧。第三个宏有问题吧。
古尔丹之手用的应该比腐蚀术频繁吧。腐蚀术十八秒持续时间，古尔丹之手12秒CD。这个宏应该是用宏9秒后刷新，然后再用腐蚀术，末日，古尔丹吧。但是末日15秒一跳在你上新末日的时候，你的旧末日还没跳过。腐蚀术，末日，古尔丹之手（3秒-3.5秒时间，这个0.5秒的波动取决于你的急速影响的古尔丹之手的施法时间，就算有嗜血古尔丹之手施法少于1秒但是也会有1秒公共CD）但是然后如果接着用这个宏的话就会释放腐蚀术，这时你的腐蚀术还有至少9秒持续时间。但是过你延迟的话又会浪费古尔丹的CD。

---

求恶魔SS和痛苦术士的输出宏 我是亡灵术士。视频